Mercurial > vim

view src/testdir/test_help.vim @ 17586:ea5d6716b82e v8.1.1790

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.1.1790: :mkvimrc is not tested commit https://github.com/vim/vim/commit/8750026a7f6b445c43adc990141a3fe92d680b62 Author: Bram Moolenaar <Bram@vim.org> Date: Thu Aug 1 23:05:49 2019 +0200 patch 8.1.1790: :mkvimrc is not tested Problem: :mkvimrc is not tested. Solution: Add a test.
author Bram Moolenaar <Bram@vim.org>
date Thu, 01 Aug 2019 23:15:04 +0200
parents e1deb00ffc27
children d0dfb3b0fe31
line wrap: on
line source

" Tests for :help

func Test_help_restore_snapshot()
  help
  set buftype=
  help
  edit x
  help
  helpclose
endfunc

func Test_help_errors()
  call assert_fails('help doesnotexist', 'E149:')
  call assert_fails('help!', 'E478:')

  new
  set keywordprg=:help
  call setline(1, "   ")
  call assert_fails('normal VK', 'E349:')
  bwipe!
endfunc

func Test_help_keyword()
  new
  set keywordprg=:help
  call setline(1, "  Visual ")
  normal VK
  call assert_match('^Visual mode', getline('.'))
  call assert_equal('help', &ft)
  close
  bwipe!
endfunc

func Test_help_local_additions()
  call mkdir('Xruntime/doc', 'p')
  call writefile(['*mydoc.txt* my awesome doc'], 'Xruntime/doc/mydoc.txt')
  call writefile(['*mydoc-ext.txt* my extended awesome doc'], 'Xruntime/doc/mydoc-ext.txt')
  let rtp_save = &rtp
  set rtp+=./Xruntime
  help
  1
  call search('mydoc.txt')
  call assert_equal('|mydoc.txt| my awesome doc', getline('.'))
  1
  call search('mydoc-ext.txt')
  call assert_equal('|mydoc-ext.txt| my extended awesome doc', getline('.'))
  close

  call delete('Xruntime', 'rf')
  let &rtp = rtp_save
endfunc