patch 9.0.1679: Cleanup Tests from leftover files Commit: https://github.com/vim/vim/commit/84bc00e9b52b1174888f2f696f8b628a83c49988 Author: Christian Brabandt <cb@256bit.org> Date: Thu Jul 13 11:45:54 2023 +0200 patch 9.0.1679: Cleanup Tests from leftover files Problem: Tests may leave leftover files around Solution: Clean up tests and remove files There were a few failures in 'linux (huge, gcc, testgui, true, true)' e.g. here: https://github.com/vim/vim/actions/runs/5497376153/jobs/10018060156 ,---- | Error detected while processing command line..script /home/runner/work/vim/vim/src/testdir/runtest.vim[585]..function RunTheTest[54]..Test_lvimgrep_crash[16]..TestTimeout[12]..VimLeavePre Autocommands for "*"..function EarlyExit[7]..FinishTesting: | line 70: | E445: Other window contains changes | E937: Attempt to delete a buffer that is in use: Xtest_stable_xxd.txt | E937: Attempt to delete a buffer that is in use: Xtest_stable_xxd.txt | E937: Attempt to delete a buffer that is in use: Xtest_stable_xxd.txtmalloc(): unsorted double linked list corrupted `---- Which is puzzling, because the Xtest_stable_xxd file should have been long gone after test_crypt.vim is run (and definitely no longer be staying around in test_quickfix.vim). So try to clean up properly after a test script is run, just in case any X<file> is still around. During testing, a found a few leftover files, which I also fixed in the relevant test-file. Unfortunately, the test workflow 'linux (huge, gcc, testgui, true, true)' now seems to fail with 'E1230: Encryption: sodium_mlock()' in test_crypt.vim. Hopefully this is only temporary.

" Inserts 2 million lines with consecutive integers starting from 1
" (essentially, the output of GNU's seq 1 2000000), writes them to Xtest
" and writes its cksum to test.out.
"
" We need 2 million lines to trigger a call to mf_hash_grow().  If it would mess
" up the lines the checksum would differ.
"
" cksum is part of POSIX and so should be available on most Unixes.
" If it isn't available then the test will be skipped.

source check.vim

func Test_File_Size()
  CheckExecutable cksum

  new
  set fileformat=unix undolevels=-1
  for i in range(1, 2000000, 100)
    call append(i, range(i, i + 99))
  endfor

  1delete
  w! Xtest
  let res = systemlist('cksum Xtest')[0]
  let res = substitute(res, "\r", "", "")
  call assert_equal('3678979763 14888896 Xtest', res)

  enew!
  call delete('Xtest')
  set fileformat& undolevels&
endfunc

" Test for writing and reading a file of over 100 Kbyte
func Test_File_Read_Write()
  enew!

  " Create a file with the following contents
  " 1 line: "This is the start"
  " 3001 lines: "This is the leader"
  " 1 line: "This is the middle"
  " 3001 lines: "This is the trailer"
  " 1 line: "This is the end"
  call append(0, "This is the start")
  call append(1, repeat(["This is the leader"], 3001))
  call append(3002, "This is the middle")
  call append(3003, repeat(["This is the trailer"], 3001))
  call append(6004, "This is the end")

  write! Xtest
  enew!
  edit! Xtest

  call assert_equal("This is the start", getline(1))
  call assert_equal("This is the middle", getline(3003))
  call assert_equal("This is the end", getline(6005))

  enew!
  call delete("Xtest")
endfunc

" vim: shiftwidth=2 sts=2 expandtab