Mercurial > vim

view src/testdir/test_messages.vim @ 13238:e0dcfd3dbb52 v8.0.1493

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.1493: completion items cannot be annotated commit https://github.com/vim/vim/commit/9b56a57cdae31f7a2c85d440392bf63d3253a158 Author: Bram Moolenaar <Bram@vim.org> Date: Sat Feb 10 16:19:32 2018 +0100 patch 8.0.1493: completion items cannot be annotated Problem: Completion items cannot be annotated. Solution: Add a "user_data" entry to the completion item. (Ben Jackson, coses #2608, closes #2508)
author Christian Brabandt <cb@256bit.org>
date Sat, 10 Feb 2018 16:30:06 +0100
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction