view runtime/syntax/cabalconfig.vim @ 30186:d9768ddc26fd v9.0.0429

patch 9.0.0429: not all keys are tested for the MS-Windows GUI Commit: https://github.com/vim/vim/commit/0adae2da17598669e442ba38547ab18a6c1406de Author: Yegappan Lakshmanan <yegappan@yahoo.com> Date: Fri Sep 9 17:39:02 2022 +0100 patch 9.0.0429: not all keys are tested for the MS-Windows GUI Problem: Not all keys are tested for the MS-Windows GUI. Solution: Add more key codes to the list. (Yegappan Lakshmanan, closes #11097)
author Bram Moolenaar <Bram@vim.org>
date Fri, 09 Sep 2022 18:45:03 +0200
parents 29c5f168c6fd
children
line wrap: on
line source

" Vim syntax file
" Language:		Cabal Config
" Maintainer:		profunctor@pm.me
" Last Change:		Marcin Szamotulski
" Original Author:	Marcin Szamotulski

if exists("b:current_syntax")
  finish
endif

syn match CabalConfigSection /^\S[[:alpha:]]\+\%(-[[:alpha:]]\+\)*[^:]*$/
syn region CabalConfigRegion matchgroup=CabalConfigKey start=/^\s*[[:alpha:]]\+\%(-[[:alpha:]]\+\)*:/ matchgroup=NONE end=/$/ contains=CabalConfigSeparator,CabalConfigKeyword,CabalConfigPath keepend
syn match CabalConfigComment /^\s*--.*$/
syn match CabalConfigValue /.*$/ contained
syn match CabalConfigKey /[[:alpha:]]\+\%(-[[:alpha:]]\+\)*\ze:/
syn keyword CabalConfigSeparator : contained
syn match CabalConfigVariable /\$[[:alpha:]]\+/
syn keyword CabalConfigKeyword True False ghc
syn match CabalConfigPath /\%([[:alpha:]]\+:\)\?\%(\/[[:print:]]\+\)\+/

hi def link CabalConfigComment Comment
hi def link CabalConfigSection Title
hi def link CabalConfigKey Statement
hi def link CabalConfigSeparator NonText
hi def link CabalConfigValue Normal
hi def link CabalConfigVariable Identifier
hi def link CabalConfigKeyword Keyword
hi def link CabalConfigPath Directory

let b:current_syntax = "cabal.config"