Mercurial > vim

view src/testdir/test_tabline.vim @ 14966:d65790af8514 v8.1.0494

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.1.0494: functions do not check for a window ID in other tabs commit https://github.com/vim/vim/commit/babfcf54ae9bf9570eddf4958a553635cd589e21 Author: Bram Moolenaar <Bram@vim.org> Date: Thu Oct 25 13:11:16 2018 +0200 patch 8.1.0494: functions do not check for a window ID in other tabs Problem: Functions do not check for a window ID in other tabs. Solution: Also find the window ID in other than the current tab.
author Bram Moolenaar <Bram@vim.org>
date Thu, 25 Oct 2018 13:15:05 +0200
parents ccab37bb9ac9
children 325e4a8ba1b6
line wrap: on
line source

function! TablineWithCaughtError()
  let s:func_in_tabline_called = 1
  try
    call eval('unknown expression')
  catch
  endtry
  return ''
endfunction

function! TablineWithError()
  let s:func_in_tabline_called = 1
  call eval('unknown expression')
  return ''
endfunction

function! Test_caught_error_in_tabline()
  if has('gui')
    set guioptions-=e
  endif
  let showtabline_save = &showtabline
  set showtabline=2
  let s:func_in_tabline_called = 0
  let tabline = '%{TablineWithCaughtError()}'
  let &tabline = tabline
  redraw!
  call assert_true(s:func_in_tabline_called)
  call assert_equal(tabline, &tabline)
  set tabline=
  let &showtabline = showtabline_save
endfunction

function! Test_tabline_will_be_disabled_with_error()
  if has('gui')
    set guioptions-=e
  endif
  let showtabline_save = &showtabline
  set showtabline=2
  let s:func_in_tabline_called = 0
  let tabline = '%{TablineWithError()}'
  try
    let &tabline = tabline
    redraw!
  catch
  endtry
  call assert_true(s:func_in_tabline_called)
  call assert_equal('', &tabline)
  set tabline=
  let &showtabline = showtabline_save
endfunction