Mercurial > vim

view src/testdir/test_messages.vim @ 13476:d130044d4f1f v8.0.1612

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.1612: need to close terminal after shell stopped commit https://github.com/vim/vim/commit/1dd98334d6daee8abefcd640291d4b777d9f0f96 Author: Bram Moolenaar <Bram@vim.org> Date: Fri Mar 16 22:54:53 2018 +0100 patch 8.0.1612: need to close terminal after shell stopped Problem: Need to close terminal after shell stopped. Solution: Make :terminal without argument close the window by default.
author Christian Brabandt <cb@256bit.org>
date Fri, 16 Mar 2018 23:00:07 +0100
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction