view src/testdir/test_matchadd_conceal_utf8.vim @ 21246:ce655819d9ec v8.2.1174

patch 8.2.1174: no test for the "recording @x" message Commit: https://github.com/vim/vim/commit/11a5b19a8ce543c258832ac53d771047f4e1061d Author: Bram Moolenaar <Bram@vim.org> Date: Fri Jul 10 21:17:51 2020 +0200 patch 8.2.1174: no test for the "recording @x" message Problem: No test for the "recording @x" message. Solution: Add a test. (Dominique Pell?, closes https://github.com/vim/vim/issues/6427)
author Bram Moolenaar <Bram@vim.org>
date Fri, 10 Jul 2020 21:30:04 +0200
parents 0dcc2ee838dd
children 08940efa6b4e
line wrap: on
line source

" Test for matchadd() and conceal feature using utf-8.

source check.vim
CheckFeature conceal

if !has('gui_running') && has('unix')
  set term=ansi
endif

func s:screenline(lnum) abort
  let line = []
  for c in range(1, winwidth(0))
    call add(line, nr2char(a:lnum->screenchar(c)))
  endfor
  return s:trim(join(line, ''))
endfunc

func s:trim(str) abort
  return matchstr(a:str,'^\s*\zs.\{-}\ze\s*$')
endfunc

func Test_match_using_multibyte_conceal_char()
  new
  setlocal concealcursor=n conceallevel=1

  1put='# This is a Test'
  "             1234567890123456
  let expect = '#ˑThisˑisˑaˑTest'

  call cursor(1, 1)
  call matchadd('Conceal', '\%2l ', 20, -1, {'conceal': "\u02d1"})
  redraw!

  let lnum = 2
  call assert_equal(expect, s:screenline(lnum))
  call assert_notequal(screenattr(lnum, 1), screenattr(lnum, 2))
  call assert_equal(screenattr(lnum, 2), screenattr(lnum, 7))
  call assert_equal(screenattr(lnum, 2), screenattr(lnum, 10))
  call assert_equal(screenattr(lnum, 2), screenattr(lnum, 12))
  call assert_equal(screenattr(lnum, 1), screenattr(lnum, 16))

  quit!
endfunc