view runtime/syntax/pbtxt.vim @ 30948:cdb345a925d0 v9.0.0808

patch 9.0.0808: jsonnet filetype detection has a typo Commit: https://github.com/vim/vim/commit/6c8bc37a1083d17447156592f6f52da2d40b4855 Author: Maxime Brunet <max@brnt.mx> Date: Thu Oct 20 20:52:44 2022 +0100 patch 9.0.0808: jsonnet filetype detection has a typo Problem: jsonnet filetype detection has a typo. Solution: Change "libjsonnet" to "libsonnet". (Maxime Brunet, closes https://github.com/vim/vim/issues/11412)
author Bram Moolenaar <Bram@vim.org>
date Thu, 20 Oct 2022 22:00:04 +0200
parents e7c125224b1a
children
line wrap: on
line source

" Vim syntax file
" Language:             Protobuf Text Format
" Maintainer:           Lakshay Garg <lakshayg@outlook.in>
" Last Change:          2020 Nov 17
" Homepage:             https://github.com/lakshayg/vim-pbtxt

if exists("b:current_syntax")
  finish
endif

let s:cpo_save = &cpo
set cpo&vim

syn case ignore

syn keyword pbtxtTodo     TODO FIXME contained
syn keyword pbtxtBool     true false contained

syn match   pbtxtInt      display   "\<\(0\|[1-9]\d*\)\>"
syn match   pbtxtHex      display   "\<0[xX]\x\+\>"
syn match   pbtxtFloat    display   "\(0\|[1-9]\d*\)\=\.\d*"
syn match   pbtxtMessage  display   "^\s*\w\+\s*{"me=e-1
syn match   pbtxtField    display   "^\s*\w\+:"me=e-1
syn match   pbtxtEnum     display   ":\s*\a\w\+"ms=s+1   contains=pbtxtBool
syn region  pbtxtString   start=+"+ skip=+\\"+ end=+"+   contains=@Spell
syn region  pbtxtComment  start="#" end="$"      keepend contains=pbtxtTodo,@Spell

hi def link pbtxtTodo     Todo
hi def link pbtxtBool     Boolean
hi def link pbtxtInt      Number
hi def link pbtxtHex      Number
hi def link pbtxtFloat    Float
hi def link pbtxtMessage  Structure
hi def link pbtxtField    Identifier
hi def link pbtxtEnum     Define
hi def link pbtxtString   String
hi def link pbtxtComment  Comment

let b:current_syntax = "pbtxt"

let &cpo = s:cpo_save
unlet s:cpo_save

" vim: nowrap sw=2 sts=2 ts=8 noet