Mercurial > vim

view runtime/syntax/limits.vim @ 19799:bde8020fb283 v8.2.0456

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.0456: Test_confirm_cmd is flaky Commit: https://github.com/vim/vim/commit/72749f062f15c7147f512bc581695c25ad78fb4e Author: Bram Moolenaar <Bram@vim.org> Date: Thu Mar 26 20:51:43 2020 +0100 patch 8.2.0456: Test_confirm_cmd is flaky Problem: Test_confirm_cmd is flaky. Solution: Add a term_wait() call. (closes https://github.com/vim/vim/issues/5854)
author Bram Moolenaar <Bram@vim.org>
date Thu, 26 Mar 2020 21:00:04 +0100
parents 1218c5353e2b
children
line wrap: on
line source

" Vim syntax file
" Language:             limits(5) configuration file
" Previous Maintainer:  Nikolai Weibull <now@bitwi.se>
" Latest Revision:      2006-04-19

if exists("b:current_syntax")
  finish
endif

let s:cpo_save = &cpo
set cpo&vim

syn keyword limitsTodo    contained TODO FIXME XXX NOTE

syn region  limitsComment display oneline start='^\s*#' end='$'
                          \ contains=limitsTodo,@Spell

syn match   limitsBegin   display '^'
                          \ nextgroup=limitsUser,limitsDefault,limitsComment
                          \ skipwhite

syn match   limitsUser    contained '[^ \t#*]\+'
                          \ nextgroup=limitsLimit,limitsDeLimit skipwhite

syn match   limitsDefault contained '*'
                          \ nextgroup=limitsLimit,limitsDeLimit skipwhite

syn match   limitsLimit   contained '[ACDFMNRSTUKLP]' nextgroup=limitsNumber
syn match   limitsDeLimit contained '-'

syn match   limitsNumber  contained '\d\+\>' nextgroup=limitsLimit skipwhite

hi def link limitsTodo    Todo
hi def link limitsComment Comment
hi def link limitsUser    Keyword
hi def link limitsDefault Macro
hi def link limitsLimit   Identifier
hi def link limitsDeLimit Special
hi def link limitsNumber  Number

let b:current_syntax = "limits"

let &cpo = s:cpo_save
unlet s:cpo_save