Mercurial > vim

view src/testdir/test_matchadd_conceal_utf8.vim @ 15539:ba876ced4f1f v8.1.0777

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.1.0777: Win32: using pipes for channel does not work well commit https://github.com/vim/vim/commit/b091f30bf38eacb31b9d8c97c82c7e0af9866301 Author: Bram Moolenaar <Bram@vim.org> Date: Sat Jan 19 14:37:00 2019 +0100 patch 8.1.0777: Win32: using pipes for channel does not work well Problem: Win32: using pipes for channel does not work well. Solution: Use a larger buffer and handle overlaps. (Yasuhiro Matsumoto, closes #3782)
author Bram Moolenaar <Bram@vim.org>
date Sat, 19 Jan 2019 14:45:06 +0100
parents 63b02fcf1361
children 2dcaa860e3fc
line wrap: on
line source

" Test for matchadd() and conceal feature using utf-8.
if !has('conceal') || !has('multi_byte')
  finish
endif

if !has('gui_running') && has('unix')
  set term=ansi
endif

func s:screenline(lnum) abort
  let line = []
  for c in range(1, winwidth(0))
    call add(line, nr2char(screenchar(a:lnum, c)))
  endfor
  return s:trim(join(line, ''))
endfunc

func s:trim(str) abort
  return matchstr(a:str,'^\s*\zs.\{-}\ze\s*$')
endfunc

func Test_match_using_multibyte_conceal_char()
  new
  setlocal concealcursor=n conceallevel=1

  1put='# This is a Test'
  "             1234567890123456
  let expect = '#ˑThisˑisˑaˑTest'

  call cursor(1, 1)
  call matchadd('Conceal', '\%2l ', 20, -1, {'conceal': "\u02d1"})
  redraw!

  let lnum = 2
  call assert_equal(expect, s:screenline(lnum))
  call assert_notequal(screenattr(lnum, 1), screenattr(lnum, 2))
  call assert_equal(screenattr(lnum, 2), screenattr(lnum, 7))
  call assert_equal(screenattr(lnum, 2), screenattr(lnum, 10))
  call assert_equal(screenattr(lnum, 2), screenattr(lnum, 12))
  call assert_equal(screenattr(lnum, 1), screenattr(lnum, 16))

  quit!
endfunc