Mercurial > vim

view src/testdir/test_tabline.vim @ 13904:b94a9171ec7c v8.0.1823

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.1823: test for terminal stdout redirection is flaky commit https://github.com/vim/vim/commit/54c6bafa1609f2d870874d0047b394670602350e Author: Bram Moolenaar <Bram@vim.org> Date: Sat May 12 21:12:12 2018 +0200 patch 8.0.1823: test for terminal stdout redirection is flaky Problem: Test for terminal stdout redirection is flaky. Solution: Wait for the job to finish.
author Christian Brabandt <cb@256bit.org>
date Sat, 12 May 2018 21:15:07 +0200
parents ccab37bb9ac9
children 325e4a8ba1b6
line wrap: on
line source

function! TablineWithCaughtError()
  let s:func_in_tabline_called = 1
  try
    call eval('unknown expression')
  catch
  endtry
  return ''
endfunction

function! TablineWithError()
  let s:func_in_tabline_called = 1
  call eval('unknown expression')
  return ''
endfunction

function! Test_caught_error_in_tabline()
  if has('gui')
    set guioptions-=e
  endif
  let showtabline_save = &showtabline
  set showtabline=2
  let s:func_in_tabline_called = 0
  let tabline = '%{TablineWithCaughtError()}'
  let &tabline = tabline
  redraw!
  call assert_true(s:func_in_tabline_called)
  call assert_equal(tabline, &tabline)
  set tabline=
  let &showtabline = showtabline_save
endfunction

function! Test_tabline_will_be_disabled_with_error()
  if has('gui')
    set guioptions-=e
  endif
  let showtabline_save = &showtabline
  set showtabline=2
  let s:func_in_tabline_called = 0
  let tabline = '%{TablineWithError()}'
  try
    let &tabline = tabline
    redraw!
  catch
  endtry
  call assert_true(s:func_in_tabline_called)
  call assert_equal('', &tabline)
  set tabline=
  let &showtabline = showtabline_save
endfunction