Mercurial > vim

view src/testdir/test_expand_dllpath.vim @ 12632:b1a7e3968a31 v8.0.1194

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.1194: actual fg and bg colors of terminal are unknown commit https://github.com/vim/vim/commit/65e4c4f6868882a380c319632a1728a5e7d274ad Author: Bram Moolenaar <Bram@vim.org> Date: Sat Oct 14 23:24:25 2017 +0200 patch 8.0.1194: actual fg and bg colors of terminal are unknown Problem: Actual fg and bg colors of terminal are unknown. Solution: Add t_RF. Store response to t_RB and t_RF, use for terminal.
author Christian Brabandt <cb@256bit.org>
date Sat, 14 Oct 2017 23:30:05 +0200
parents 18cda18a38e2
children 08940efa6b4e
line wrap: on
line source

func s:test_expand_dllpath(optname)
  let $TEST_EXPAND_DLLPATH = '/dllpath/lib' . substitute(a:optname, '\zedll$', '.', '')
  execute 'let dllpath_save = &' . a:optname
  try
    execute 'set ' . a:optname . '=$TEST_EXPAND_DLLPATH' 
    execute 'call assert_equal("' . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 

    execute 'set ' . a:optname . '=~' . $TEST_EXPAND_DLLPATH
    let home = substitute($HOME, '\\', '/', 'g')
    execute 'call assert_equal("' . home . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 
  finally
    execute 'let &' . a:optname . ' = dllpath_save'
    let $TEST_EXPAND_DLLPATH = ''
  endtry
endfunc

func s:generate_test_if_exists(optname)
  if exists('+' . a:optname)
    execute join([
          \ 'func Test_expand_' . a:optname . '()',
          \ '  call s:test_expand_dllpath("' . a:optname . '")',
          \ 'endfunc'
          \ ], "\n")
  endif
endfunc

call s:generate_test_if_exists('luadll')
call s:generate_test_if_exists('perldll')
call s:generate_test_if_exists('pythondll')
call s:generate_test_if_exists('pythonthreedll')
call s:generate_test_if_exists('rubydll')
call s:generate_test_if_exists('tcldll')