Mercurial > vim

view src/testdir/test_messages.vim @ 11083:ae86651164d7 v8.0.0430

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.0430: options test fails or hangs on MS-Windows commit https://github.com/vim/vim/commit/bb962262eb6b18d93161d7506317d215ae80bfe5 Author: Bram Moolenaar <Bram@vim.org> Date: Wed Mar 8 00:01:35 2017 +0100 patch 8.0.0430: options test fails or hangs on MS-Windows Problem: Options test fails or hangs on MS-Windows. Solution: Run it separately instead of part of test_alot. Use "-S" instead of "-u" to run the script. Fix failures.
author Christian Brabandt <cb@256bit.org>
date Wed, 08 Mar 2017 00:15:04 +0100
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction