Mercurial > vim

view src/testdir/test_tabline.vim @ 13215:ae5f855a64be v8.0.1482

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.1482: using feedkeys() does not work to test completion commit https://github.com/vim/vim/commit/02ae9b4a93deea4993d7abe20485f91f1cce5e36 Author: Bram Moolenaar <Bram@vim.org> Date: Fri Feb 9 15:06:02 2018 +0100 patch 8.0.1482: using feedkeys() does not work to test completion Problem: Using feedkeys() does not work to test Insert mode completion. (Lifepillar) Solution: Do not check for typed keys when executing :normal or feedkeys(). Fix thesaurus completion not working when 'complete' is empty.
author Christian Brabandt <cb@256bit.org>
date Fri, 09 Feb 2018 15:15:06 +0100
parents ccab37bb9ac9
children 325e4a8ba1b6
line wrap: on
line source

function! TablineWithCaughtError()
  let s:func_in_tabline_called = 1
  try
    call eval('unknown expression')
  catch
  endtry
  return ''
endfunction

function! TablineWithError()
  let s:func_in_tabline_called = 1
  call eval('unknown expression')
  return ''
endfunction

function! Test_caught_error_in_tabline()
  if has('gui')
    set guioptions-=e
  endif
  let showtabline_save = &showtabline
  set showtabline=2
  let s:func_in_tabline_called = 0
  let tabline = '%{TablineWithCaughtError()}'
  let &tabline = tabline
  redraw!
  call assert_true(s:func_in_tabline_called)
  call assert_equal(tabline, &tabline)
  set tabline=
  let &showtabline = showtabline_save
endfunction

function! Test_tabline_will_be_disabled_with_error()
  if has('gui')
    set guioptions-=e
  endif
  let showtabline_save = &showtabline
  set showtabline=2
  let s:func_in_tabline_called = 0
  let tabline = '%{TablineWithError()}'
  try
    let &tabline = tabline
    redraw!
  catch
  endtry
  call assert_true(s:func_in_tabline_called)
  call assert_equal('', &tabline)
  set tabline=
  let &showtabline = showtabline_save
endfunction