Mercurial > vim

view runtime/syntax/group.vim @ 11075:a8be0c7169b1 v8.0.0426

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.0426: insufficient testing for statusline commit https://github.com/vim/vim/commit/300af82eca3dd5fec6be5516f16c9fd344ae104b Author: Bram Moolenaar <Bram@vim.org> Date: Mon Mar 6 20:28:10 2017 +0100 patch 8.0.0426: insufficient testing for statusline Problem: Insufficient testing for statusline. Solution: Add several tests. (Dominique Pelle, closes https://github.com/vim/vim/issues/1534)
author Christian Brabandt <cb@256bit.org>
date Mon, 06 Mar 2017 20:30:04 +0100
parents 1218c5353e2b
children
line wrap: on
line source

" Vim syntax file
" Language:             group(5) user group file
" Previous Maintainer:  Nikolai Weibull <now@bitwi.se>
" Latest Revision:      2012-08-05

if exists("b:current_syntax")
  finish
endif

let s:cpo_save = &cpo
set cpo&vim

syn match   groupBegin          display '^' nextgroup=groupName

syn match   groupName           contained display '[^:]\+'
                                \ nextgroup=groupPasswordColon

syn match   groupPasswordColon  contained display ':'
                                \ nextgroup=groupPassword,groupShadow

syn match   groupPassword       contained display '[^:]*'
                                \ nextgroup=groupGIDColon

syn match   groupShadow         contained display '[x*]' nextgroup=groupGIDColon

syn match   groupGIDColon       contained display ':' nextgroup=groupGID

syn match   groupGID            contained display '\d*'
                                \ nextgroup=groupUserListColon

syn match   groupUserListColon  contained display ':' nextgroup=groupUserList

syn match   groupUserList       contained '[^,]\+'
                                \ nextgroup=groupUserListSep

syn match   groupUserListSep    contained display ',' nextgroup=groupUserList

hi def link groupDelimiter      Normal
hi def link groupName           Identifier
hi def link groupPasswordColon  groupDelimiter
hi def link groupPassword       Number
hi def link groupShadow         Special
hi def link groupGIDColon       groupDelimiter
hi def link groupGID            Number
hi def link groupUserListColon  groupDelimiter
hi def link groupUserList       Identifier
hi def link groupUserListSep    groupDelimiter

let b:current_syntax = "group"

let &cpo = s:cpo_save
unlet s:cpo_save