Mercurial > vim

view src/testdir/test_matchadd_conceal_utf8.vim @ 20816:9faab49c880f v8.2.0960

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.0960: cannot use :import in legacy Vim script Commit: https://github.com/vim/vim/commit/9721fb4ea3db2559aaf7f71458da8ddda30ff93e Author: Bram Moolenaar <Bram@vim.org> Date: Thu Jun 11 23:10:46 2020 +0200 patch 8.2.0960: cannot use :import in legacy Vim script Problem: Cannot use :import in legacy Vim script. Solution: Support :import in any Vim script.
author Bram Moolenaar <Bram@vim.org>
date Thu, 11 Jun 2020 23:15:03 +0200
parents 0dcc2ee838dd
children 08940efa6b4e
line wrap: on
line source

" Test for matchadd() and conceal feature using utf-8.

source check.vim
CheckFeature conceal

if !has('gui_running') && has('unix')
  set term=ansi
endif

func s:screenline(lnum) abort
  let line = []
  for c in range(1, winwidth(0))
    call add(line, nr2char(a:lnum->screenchar(c)))
  endfor
  return s:trim(join(line, ''))
endfunc

func s:trim(str) abort
  return matchstr(a:str,'^\s*\zs.\{-}\ze\s*$')
endfunc

func Test_match_using_multibyte_conceal_char()
  new
  setlocal concealcursor=n conceallevel=1

  1put='# This is a Test'
  "             1234567890123456
  let expect = '#ˑThisˑisˑaˑTest'

  call cursor(1, 1)
  call matchadd('Conceal', '\%2l ', 20, -1, {'conceal': "\u02d1"})
  redraw!

  let lnum = 2
  call assert_equal(expect, s:screenline(lnum))
  call assert_notequal(screenattr(lnum, 1), screenattr(lnum, 2))
  call assert_equal(screenattr(lnum, 2), screenattr(lnum, 7))
  call assert_equal(screenattr(lnum, 2), screenattr(lnum, 10))
  call assert_equal(screenattr(lnum, 2), screenattr(lnum, 12))
  call assert_equal(screenattr(lnum, 1), screenattr(lnum, 16))

  quit!
endfunc