view src/testdir/test_fixeol.vim @ 19540:9f07a6c172f2 v8.2.0327

patch 8.2.0327: crash when opening and closing two popup terminal windows Commit: https://github.com/vim/vim/commit/80ae880f5fed8022c69d05dd1efee49259929cb5 Author: Bram Moolenaar <Bram@vim.org> Date: Fri Feb 28 19:11:18 2020 +0100 patch 8.2.0327: crash when opening and closing two popup terminal windows Problem: Crash when opening and closing two popup terminal windows. Solution: Check that prevwin is valid. (closes https://github.com/vim/vim/issues/5707)
author Bram Moolenaar <Bram@vim.org>
date Fri, 28 Feb 2020 19:15:04 +0100
parents 90aaa974594e
children 08940efa6b4e
line wrap: on
line source

" Tests for 'fixeol' and 'eol'
func Test_fixeol()
  " first write two test files – with and without trailing EOL
  " use Unix fileformat for consistency
  set ff=unix
  enew!
  call setline('.', 'with eol')
  w! XXEol
  enew!
  set noeol nofixeol
  call setline('.', 'without eol')
  w! XXNoEol
  set eol fixeol
  bwipe XXEol XXNoEol

  " try editing files with 'fixeol' disabled
  e! XXEol
  normal ostays eol
  set nofixeol
  w! XXTestEol
  e! XXNoEol
  normal ostays without
  set nofixeol
  w! XXTestNoEol
  bwipe! XXEol XXNoEol XXTestEol XXTestNoEol
  set fixeol

  " Append "END" to each file so that we can see what the last written char
  " was.
  normal ggdGaEND
  w >>XXEol
  w >>XXNoEol
  w >>XXTestEol
  w >>XXTestNoEol

  call assert_equal(['with eol', 'END'], readfile('XXEol'))
  call assert_equal(['without eolEND'], readfile('XXNoEol'))
  call assert_equal(['with eol', 'stays eol', 'END'], readfile('XXTestEol'))
  call assert_equal(['without eol', 'stays withoutEND'],
	      \ readfile('XXTestNoEol'))

  call delete('XXEol')
  call delete('XXNoEol')
  call delete('XXTestEol')
  call delete('XXTestNoEol')
  set ff& fixeol& eol&
  enew!
endfunc