Mercurial > vim

view runtime/indent.vim @ 31475:9ef91bdd1ab4 v9.0.1070

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 9.0.1070: reading beyond array size Commit: https://github.com/vim/vim/commit/b26461715be41653e5982e72c794294702ecded9 Author: Bram Moolenaar <Bram@vim.org> Date: Sat Dec 17 15:35:43 2022 +0000 patch 9.0.1070: reading beyond array size Problem: Reading beyond array size. Solution: Only use name[0] and name[1], do not use "name" as a string.
author Bram Moolenaar <Bram@vim.org>
date Sat, 17 Dec 2022 16:45:03 +0100
parents 9fe2fed9bb4b
children 4027cefc2aab
line wrap: on
line source

" Vim support file to switch on loading indent files for file types
"
" Maintainer:	Bram Moolenaar <Bram@vim.org>
" Last Change:	2022 Feb 11

if exists("did_indent_on")
  finish
endif
let did_indent_on = 1

augroup filetypeindent
  au FileType * call s:LoadIndent()
augroup END

def s:LoadIndent()
  if exists("b:undo_indent")
    legacy exe b:undo_indent
    unlet! b:undo_indent b:did_indent
  endif
  var s = expand("<amatch>")
  if s != ""
    if exists("b:did_indent")
      unlet b:did_indent
    endif

    # When there is a dot it is used to separate filetype names.  Thus for
    # "aaa.bbb" load "indent/aaa.vim" and then "indent/bbb.vim".
    for name in split(s, '\.')
      exe 'runtime! indent/' .. name .. '.vim'
    endfor
  endif
enddef