view runtime/compiler/cargo.vim @ 34784:99bf06d67e43

runtime: Remove more fallback :CompilerSet definitions from compiler plugins (#14413) Commit: https://github.com/vim/vim/commit/cec44eae82c15a7daa54528696040d6eca7cc3af Author: Yinzuo Jiang <jiangyinzuo@foxmail.com> Date: Sat Apr 6 01:59:39 2024 +0800 runtime: Remove more fallback :CompilerSet definitions from compiler plugins (https://github.com/vim/vim/issues/14413) Continue with https://github.com/vim/vim/issues/14399 Signed-off-by: jiangyinzuo <jiangyinzuo@foxmail.com> Signed-off-by: Doug Kearns <dougkearns@gmail.com> Signed-off-by: Christian Brabandt <cb@256bit.org>
author Christian Brabandt <cb@256bit.org>
date Fri, 05 Apr 2024 20:00:10 +0200
parents e1df51f68736
children
line wrap: on
line source

" Vim compiler file
" Compiler:         Cargo Compiler
" Maintainer:       Damien Radtke <damienradtke@gmail.com>
" Latest Revision:  2023-09-11
"                   2024 Apr 05 by The Vim Project (removed :CompilerSet definition)
" For bugs, patches and license go to https://github.com/rust-lang/rust.vim

if exists('current_compiler')
    finish
endif
runtime compiler/rustc.vim
let current_compiler = "cargo"

" vint: -ProhibitAbbreviationOption
let s:save_cpo = &cpo
set cpo&vim
" vint: +ProhibitAbbreviationOption

if exists('g:cargo_makeprg_params')
    execute 'CompilerSet makeprg=cargo\ '.escape(g:cargo_makeprg_params, ' \|"').'\ $*'
else
    CompilerSet makeprg=cargo\ $*
endif

augroup RustCargoQuickFixHooks
    autocmd!
    autocmd QuickFixCmdPre make call cargo#quickfix#CmdPre()
    autocmd QuickFixCmdPost make call cargo#quickfix#CmdPost()
augroup END

" Ignore general cargo progress messages
CompilerSet errorformat+=
            \%-G%\\s%#Downloading%.%#,
            \%-G%\\s%#Checking%.%#,
            \%-G%\\s%#Compiling%.%#,
            \%-G%\\s%#Finished%.%#,
            \%-G%\\s%#error:\ Could\ not\ compile\ %.%#,
            \%-G%\\s%#To\ learn\ more\\,%.%#,
            \%-G%\\s%#For\ more\ information\ about\ this\ error\\,%.%#,
            \%-Gnote:\ Run\ with\ \`RUST_BACKTRACE=%.%#,
            \%.%#panicked\ at\ \\'%m\\'\\,\ %f:%l:%c

" vint: -ProhibitAbbreviationOption
let &cpo = s:save_cpo
unlet s:save_cpo
" vint: +ProhibitAbbreviationOption

" vim: set et sw=4 sts=4 ts=8: