Mercurial > vim

view src/testdir/test_messages.vim @ 11242:9612b93820a4 v8.0.0507

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.0507: client-server tests fail when $DISPLAY is not set commit https://github.com/vim/vim/commit/a2845b8f5a3058c8c89699771ffd4d69513b097d Author: Bram Moolenaar <Bram@vim.org> Date: Sat Mar 25 15:20:06 2017 +0100 patch 8.0.0507: client-server tests fail when $DISPLAY is not set Problem: Client-server tests fail when $DISPLAY is not set. Solution: Check for E240 before running the test.
author Christian Brabandt <cb@256bit.org>
date Sat, 25 Mar 2017 15:30:04 +0100
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction