view runtime/ftplugin/udevrules.vim @ 33494:8b7a2ea22a86 v9.0.1997

patch 9.0.1997: Some unused code in move.c and string.c Commit: https://github.com/vim/vim/commit/580c1fcb4ad85360cd3a361c3c8e37b534153d60 Author: dundargoc <gocdundar@gmail.com> Date: Fri Oct 6 19:41:14 2023 +0200 patch 9.0.1997: Some unused code in move.c and string.c Problem: Some unused code in move.c and string.c Solution: Remove it closes: #13288 Signed-off-by: Christian Brabandt <cb@256bit.org> Co-authored-by: dundargoc <gocdundar@gmail.com>
author Christian Brabandt <cb@256bit.org>
date Fri, 06 Oct 2023 19:45:05 +0200
parents 5510af40c77b
children c252fbfde41d
line wrap: on
line source

" Vim filetype plugin file
" Language:             udev(8) rules file
" Previous Maintainer:  Nikolai Weibull <now@bitwi.se>
" Latest Revision:      2008-07-09

if exists("b:did_ftplugin")
  finish
endif
let b:did_ftplugin = 1

let s:cpo_save = &cpo
set cpo&vim

let b:undo_ftplugin = "setl com< cms< fo<"

setlocal comments=:# commentstring=#\ %s formatoptions-=t formatoptions+=croql

if has('unix') && executable('less')
  if !has('gui_running')
    command -buffer -nargs=1 Sman
          \ silent exe '!' . 'LESS= MANPAGER="less --pattern=''^\s{,8}' . <q-args> . '\b'' --hilite-search" man ' . 'udev' |
          \ redraw!
  elseif has('terminal')
    command -buffer -nargs=1 Sman
          \ silent exe ':term ' . 'env LESS= MANPAGER="less --pattern=''' . escape('^\s{,8}' . <q-args> . '\b', '\') . ''' --hilite-search" man ' . 'udev'
  endif
  if exists(':Sman') == 2
    setlocal iskeyword+=-
    setlocal keywordprg=:Sman
    let b:undo_ftplugin .= '| setlocal keywordprg< iskeyword< | sil! delc -buffer Sman'
  endif
endif

let &cpo = s:cpo_save
unlet s:cpo_save