Mercurial > vim

view src/testdir/test_fileformat.vim @ 15519:89e76a598b30 v8.1.0767

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.1.0767: when deleting lines at the bottom signs are misplaced commit https://github.com/vim/vim/commit/c771bf901622064dc27421b04853e16b6914a295 Author: Bram Moolenaar <Bram@vim.org> Date: Thu Jan 17 17:36:45 2019 +0100 patch 8.1.0767: when deleting lines at the bottom signs are misplaced Problem: When deleting lines at the bottom signs are misplaced. Solution: Properly update the line number of signs at the end of a buffer after a delete/undo operation. (Yegappan Lakshmanan, closes #3798)
author Bram Moolenaar <Bram@vim.org>
date Thu, 17 Jan 2019 17:45:06 +0100
parents d6857a8dc07e
children 140bf183f946
line wrap: on
line source

" Test behavior of fileformat after bwipeout of last buffer

func Test_fileformat_after_bw()
  bwipeout
  set fileformat&
  if &fileformat == 'dos'
    let test_fileformats = 'unix'
  elseif &fileformat == 'unix'
    let test_fileformats = 'mac'
  else  " must be mac
    let test_fileformats = 'dos'
  endif
  exec 'set fileformats='.test_fileformats
  bwipeout!
  call assert_equal(test_fileformats, &fileformat)
  set fileformats&
endfunc

func Test_fileformat_autocommand()
  let filecnt = ["", "foobar\<CR>", "eins\<CR>", "\<CR>", "zwei\<CR>", "drei", "vier", "fünf", ""]
  let ffs = &ffs
  call writefile(filecnt, 'Xfile', 'b')
  au BufReadPre Xfile set ffs=dos ff=dos
  new Xfile
  call assert_equal('dos', &l:ff)
  call assert_equal('dos', &ffs)

  " cleanup
  call delete('Xfile')
  let &ffs = ffs
  au! BufReadPre Xfile
  bw!
endfunc