Mercurial > vim

view src/testdir/test_expand_dllpath.vim @ 20421:8590a462ad46 v8.2.0765

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.0765: In the GUI can't use all the modifiers. Commit: https://github.com/vim/vim/commit/fd615a3c901f59abddca27c6a09940be552c0f4d Author: Bram Moolenaar <Bram@vim.org> Date: Sat May 16 14:01:51 2020 +0200 patch 8.2.0765: In the GUI can't use all the modifiers. Problem: In the GUI can't use all the modifiers. (Andri M?ll) Solution: Do not apply Alt/Meta early, do it later like with the terminal. Avoid the Motif test from crashing.
author Bram Moolenaar <Bram@vim.org>
date Sat, 16 May 2020 14:15:05 +0200
parents 18cda18a38e2
children 08940efa6b4e
line wrap: on
line source

func s:test_expand_dllpath(optname)
  let $TEST_EXPAND_DLLPATH = '/dllpath/lib' . substitute(a:optname, '\zedll$', '.', '')
  execute 'let dllpath_save = &' . a:optname
  try
    execute 'set ' . a:optname . '=$TEST_EXPAND_DLLPATH' 
    execute 'call assert_equal("' . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 

    execute 'set ' . a:optname . '=~' . $TEST_EXPAND_DLLPATH
    let home = substitute($HOME, '\\', '/', 'g')
    execute 'call assert_equal("' . home . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 
  finally
    execute 'let &' . a:optname . ' = dllpath_save'
    let $TEST_EXPAND_DLLPATH = ''
  endtry
endfunc

func s:generate_test_if_exists(optname)
  if exists('+' . a:optname)
    execute join([
          \ 'func Test_expand_' . a:optname . '()',
          \ '  call s:test_expand_dllpath("' . a:optname . '")',
          \ 'endfunc'
          \ ], "\n")
  endif
endfunc

call s:generate_test_if_exists('luadll')
call s:generate_test_if_exists('perldll')
call s:generate_test_if_exists('pythondll')
call s:generate_test_if_exists('pythonthreedll')
call s:generate_test_if_exists('rubydll')
call s:generate_test_if_exists('tcldll')