Mercurial > vim

view src/testdir/test_preview.vim @ 24758:857881ec1cb5 v8.2.2917

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.2917: spellfile functionality not fully tested Commit: https://github.com/vim/vim/commit/bb162367ac77db877586086d7456685f2aeb8754 Author: Dominique Pelle <dominique.pelle@gmail.com> Date: Mon May 31 20:04:07 2021 +0200 patch 8.2.2917: spellfile functionality not fully tested Problem: Spellfile functionality not fully tested. Solution: Add tests for SFX with removal of characters, spelling suggestions with NOBREAK and others. (Dominique Pell?, closes #8293)
author Bram Moolenaar <Bram@vim.org>
date Mon, 31 May 2021 20:15:02 +0200
parents 08940efa6b4e
children 457ea0570b6f
line wrap: on
line source

" Tests for the preview window

source check.vim
CheckFeature quickfix

func Test_Psearch()
  " this used to cause ml_get errors
  help
  let wincount = winnr('$')
  0f
  ps.
  call assert_equal(wincount + 1, winnr('$'))
  pclose
  call assert_equal(wincount, winnr('$'))
  bwipe
endfunc

func Test_window_preview()
  CheckFeature quickfix

  " Open a preview window
  pedit Xa
  call assert_equal(2, winnr('$'))
  call assert_equal(0, &previewwindow)

  " Go to the preview window
  wincmd P
  call assert_equal(1, &previewwindow)
  call assert_equal('preview', win_gettype())

  " Close preview window
  wincmd z
  call assert_equal(1, winnr('$'))
  call assert_equal(0, &previewwindow)

  call assert_fails('wincmd P', 'E441:')
endfunc

func Test_window_preview_from_help()
  CheckFeature quickfix

  filetype on
  call writefile(['/* some C code */'], 'Xpreview.c')
  help
  pedit Xpreview.c
  wincmd P
  call assert_equal(1, &previewwindow)
  call assert_equal('c', &filetype)
  wincmd z

  filetype off
  close
  call delete('Xpreview.c')
endfunc

func Test_multiple_preview_windows()
  new
  set previewwindow
  new
  call assert_fails('set previewwindow', 'E590:')
  %bw!
endfunc

" vim: shiftwidth=2 sts=2 expandtab