Mercurial > vim

view runtime/ftplugin/obse.vim @ 32262:854aeaac48b7 v9.0.1462

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 9.0.1462: recursively calling :defer function if it does :qa Commit: https://github.com/vim/vim/commit/42994bf678f46dc9ca66e49f512261da8864fff6 Author: Bram Moolenaar <Bram@vim.org> Date: Mon Apr 17 19:23:45 2023 +0100 patch 9.0.1462: recursively calling :defer function if it does :qa Problem: Recursively calling :defer function if it does :qa. Solution: Clear the defer entry before calling the function. (closes https://github.com/vim/vim/issues/12266)
author Bram Moolenaar <Bram@vim.org>
date Mon, 17 Apr 2023 20:30:07 +0200
parents a7801222c9c5
children 7c7432a53a6c
line wrap: on
line source

" Vim filetype plugin file
" Language:    Oblivion Language (obl)
" Original Creator: Kat <katisntgood@gmail.com>
" Maintainer:  Kat <katisntgood@gmail.com>
" Created:     August 08, 2021
" Last Change: 13 November 2022

if exists("b:did_ftplugin")
  finish
endif

let s:cpo_save = &cpo
set cpo&vim

let b:undo_ftplugin = "setl com< cms<"

noremap <script> <buffer> <silent> [[ <nop>
noremap <script> <buffer> <silent> ]] <nop>

noremap <script> <buffer> <silent> [] <nop>
noremap <script> <buffer> <silent> ][ <nop>

setlocal commentstring=;%s
setlocal comments=:;

function s:NextSection(type, backwards, visual)
    if a:visual
        normal! gv
    endif

  if a:type == 1
    let pattern = '\v(\n\n^\S|%^)'
    let flags = 'e'
  elseif a:type == 2
    let pattern = '\v^\S.*'
    let flags = ''
  endif

  if a:backwards
    let dir = '?'
  else
    let dir = '/'
  endif

  execute 'silent normal! ' . dir . pattern . dir . flags . "\r"
endfunction

noremap <script> <buffer> <silent> ]]
  \ :call <SID>NextSection(1, 0, 0)<cr>

noremap <script> <buffer> <silent> [[
  \ :call <SID>NextSection(1, 1, 0)<cr>

noremap <script> <buffer> <silent> ][
  \ :call <SID>NextSection(2, 0, 0)<cr>

noremap <script> <buffer> <silent> []
  \ :call <SID>NextSection(2, 1, 0)<cr>

vnoremap <script> <buffer> <silent> ]]
  \ :<c-u>call <SID>NextSection(1, 0, 1)<cr>
vnoremap <script> <buffer> <silent> [[
  \ :<c-u>call <SID>NextSection(1, 1, 1)<cr>
vnoremap <script> <buffer> <silent> ][
  \ :<c-u>call <SID>NextSection(2, 0, 1)<cr>
vnoremap <script> <buffer> <silent> []
  \ :<c-u>call <SID>NextSection(2, 1, 1)<cr>

let &cpo = s:cpo_save
unlet s:cpo_save