Mercurial > vim

view src/testdir/test_source.vim @ 17936:7f3283683d97 v8.1.1964

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.1.1964: crash when using nested map() and filter() Commit: https://github.com/vim/vim/commit/c36350bca3eed8ef97061e28c38b5b89cae1f13e Author: Bram Moolenaar <Bram@vim.org> Date: Mon Sep 2 20:44:07 2019 +0200 patch 8.1.1964: crash when using nested map() and filter() Problem: Crash when using nested map() and filter(). Solution: Do not set the v:key type to string without clearing the pointer.
author Bram Moolenaar <Bram@vim.org>
date Mon, 02 Sep 2019 20:45:04 +0200
parents 8d91579414b8
children ea3ac1de7704
line wrap: on
line source

" Tests for the :source command.

func Test_source_autocmd()
  call writefile([
	\ 'let did_source = 1',
	\ ], 'Xsourced')
  au SourcePre *source* let did_source_pre = 1
  au SourcePost *source* let did_source_post = 1

  source Xsourced

  call assert_equal(g:did_source, 1)
  call assert_equal(g:did_source_pre, 1)
  call assert_equal(g:did_source_post, 1)

  call delete('Xsourced')
  au! SourcePre
  au! SourcePost
  unlet g:did_source
  unlet g:did_source_pre
  unlet g:did_source_post
endfunc

func Test_source_cmd()
  au SourceCmd *source* let did_source = expand('<afile>')
  au SourcePre *source* let did_source_pre = 2
  au SourcePost *source* let did_source_post = 2

  source Xsourced

  call assert_equal(g:did_source, 'Xsourced')
  call assert_false(exists('g:did_source_pre'))
  call assert_equal(g:did_source_post, 2)

  au! SourceCmd
  au! SourcePre
  au! SourcePost
endfunc

func Test_source_sandbox()
  new
  call writefile(["Ohello\<Esc>"], 'Xsourcehello')
  source! Xsourcehello | echo
  call assert_equal('hello', getline(1))
  call assert_fails('sandbox source! Xsourcehello', 'E48:')
  bwipe!
  call delete('Xsourcehello')
endfunc