view src/testdir/test_expand_dllpath.vim @ 11995:7df3dd3c0ac1 v8.0.0878

patch 8.0.0878: no completion for :mapclear commit https://github.com/vim/vim/commit/cae92dc3d5bdd4009910671328cd01394bfbe2cf Author: Bram Moolenaar <Bram@vim.org> Date: Sun Aug 6 15:22:15 2017 +0200 patch 8.0.0878: no completion for :mapclear Problem: No completion for :mapclear. Solution: Add completion (Nobuhiro Takasaki et al. closes https://github.com/vim/vim/issues/1943)
author Christian Brabandt <cb@256bit.org>
date Sun, 06 Aug 2017 15:30:04 +0200
parents 18cda18a38e2
children 08940efa6b4e
line wrap: on
line source

func s:test_expand_dllpath(optname)
  let $TEST_EXPAND_DLLPATH = '/dllpath/lib' . substitute(a:optname, '\zedll$', '.', '')
  execute 'let dllpath_save = &' . a:optname
  try
    execute 'set ' . a:optname . '=$TEST_EXPAND_DLLPATH' 
    execute 'call assert_equal("' . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 

    execute 'set ' . a:optname . '=~' . $TEST_EXPAND_DLLPATH
    let home = substitute($HOME, '\\', '/', 'g')
    execute 'call assert_equal("' . home . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 
  finally
    execute 'let &' . a:optname . ' = dllpath_save'
    let $TEST_EXPAND_DLLPATH = ''
  endtry
endfunc

func s:generate_test_if_exists(optname)
  if exists('+' . a:optname)
    execute join([
          \ 'func Test_expand_' . a:optname . '()',
          \ '  call s:test_expand_dllpath("' . a:optname . '")',
          \ 'endfunc'
          \ ], "\n")
  endif
endfunc

call s:generate_test_if_exists('luadll')
call s:generate_test_if_exists('perldll')
call s:generate_test_if_exists('pythondll')
call s:generate_test_if_exists('pythonthreedll')
call s:generate_test_if_exists('rubydll')
call s:generate_test_if_exists('tcldll')