view runtime/ftplugin.vim @ 31867:7d505d77f6da v9.0.1266

patch 9.0.1266: error for space before ": type" is inconsistent Commit: https://github.com/vim/vim/commit/ce93d162da8de2419c15b63286e2f72a8fe3bf2d Author: Bram Moolenaar <Bram@vim.org> Date: Mon Jan 30 21:12:34 2023 +0000 patch 9.0.1266: error for space before ": type" is inconsistent Problem: Error for space before ": type" is inconsistent. Solution: Give E1059 in more places. (closes https://github.com/vim/vim/issues/11868)
author Bram Moolenaar <Bram@vim.org>
date Mon, 30 Jan 2023 22:15:03 +0100
parents 9fe2fed9bb4b
children 4027cefc2aab
line wrap: on
line source

vim9script noclear

# Vim support file to switch on loading plugins for file types
#
# Maintainer:	Bram Moolenaar <Bram@vim.org>
# Last change:	2022 Feb 11

if exists("g:did_load_ftplugin")
  finish
endif
g:did_load_ftplugin = 1

augroup filetypeplugin
  au FileType * call LoadFTPlugin()
augroup END

if exists('*LoadFTPlugin')
  # No need to define the function again.
  finish
endif

def LoadFTPlugin()
  if exists("b:undo_ftplugin")
    # We assume b:undo_ftplugin is using legacy script syntax
    legacy exe b:undo_ftplugin
    unlet! b:undo_ftplugin b:did_ftplugin
  endif

  var s = expand("<amatch>")
  if s != ""
    if &cpo =~# "S" && exists("b:did_ftplugin")
      # In compatible mode options are reset to the global values, need to
      # set the local values also when a plugin was already used.
      unlet b:did_ftplugin
    endif

    # When there is a dot it is used to separate filetype names.  Thus for
    # "aaa.bbb" load "aaa" and then "bbb".
    for name in split(s, '\.')
      exe 'runtime! ftplugin/' .. name .. '.vim ftplugin/' .. name .. '_*.vim ftplugin/' .. name .. '/*.vim'
    endfor
  endif
enddef