Mercurial > vim

view runtime/syntax/slpspi.vim @ 7718:6ebd8bdf41bc v7.4.1157

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
commit https://github.com/vim/vim/commit/f95534c3d411084d1b6112fe64f6108bf7acbb92 Author: Bram Moolenaar <Bram@vim.org> Date: Sat Jan 23 21:59:52 2016 +0100 patch 7.4.1157 Problem: type() does not work for v:true, v:none, etc. Solution: Add new type numbers.
author Christian Brabandt <cb@256bit.org>
date Sat, 23 Jan 2016 22:00:05 +0100
parents 1f3b1021f002
children 1218c5353e2b
line wrap: on
line source

" Vim syntax file
" Language:         RFC 2614 - An API for Service Location SPI file
" Maintainer:       Nikolai Weibull <now@bitwi.se>
" Latest Revision:  2006-04-19

if exists("b:current_syntax")
  finish
endif

let s:cpo_save = &cpo
set cpo&vim

syn keyword slpspiTodo          contained TODO FIXME XXX NOTE

syn region  slpspiComment       display oneline start='^[#;]' end='$'
                                \ contains=slpspiTodo,@Spell

syn match   slpspiBegin         display '^'
                                \ nextgroup=slpspiKeyType,
                                \ slpspiComment skipwhite

syn keyword slpspiKeyType       contained PRIVATE PUBLIC
                                \ nextgroup=slpspiString skipwhite

syn match   slpspiString        contained '\S\+'
                                \ nextgroup=slpspiKeyFile skipwhite

syn match   slpspiKeyFile       contained '\S\+'

hi def link slpspiTodo          Todo
hi def link slpspiComment       Comment
hi def link slpspiKeyType       Type
hi def link slpspiString        Identifier
hi def link slpspiKeyFile       String

let b:current_syntax = "slpspi"

let &cpo = s:cpo_save
unlet s:cpo_save