Mercurial > vim

view runtime/syntax/group.vim @ 10196:66658966ac2e v7.4.2367

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
commit https://github.com/vim/vim/commit/edeb846c1f04a49466992077eaea3396838bf4fd Author: Bram Moolenaar <Bram@vim.org> Date: Mon Sep 12 13:32:02 2016 +0200 patch 7.4.2367 Problem: Test runner misses a comma. Solution: Add the comma.
author Christian Brabandt <cb@256bit.org>
date Mon, 12 Sep 2016 13:45:06 +0200
parents 536aa8b0c934
children 1218c5353e2b
line wrap: on
line source

" Vim syntax file
" Language:         group(5) user group file
" Maintainer:       Nikolai Weibull <now@bitwi.se>
" Latest Revision:  2012-08-05

if exists("b:current_syntax")
  finish
endif

let s:cpo_save = &cpo
set cpo&vim

syn match   groupBegin          display '^' nextgroup=groupName

syn match   groupName           contained display '[^:]\+'
                                \ nextgroup=groupPasswordColon

syn match   groupPasswordColon  contained display ':'
                                \ nextgroup=groupPassword,groupShadow

syn match   groupPassword       contained display '[^:]*'
                                \ nextgroup=groupGIDColon

syn match   groupShadow         contained display '[x*]' nextgroup=groupGIDColon

syn match   groupGIDColon       contained display ':' nextgroup=groupGID

syn match   groupGID            contained display '\d*'
                                \ nextgroup=groupUserListColon

syn match   groupUserListColon  contained display ':' nextgroup=groupUserList

syn match   groupUserList       contained '[^,]\+'
                                \ nextgroup=groupUserListSep

syn match   groupUserListSep    contained display ',' nextgroup=groupUserList

hi def link groupDelimiter      Normal
hi def link groupName           Identifier
hi def link groupPasswordColon  groupDelimiter
hi def link groupPassword       Number
hi def link groupShadow         Special
hi def link groupGIDColon       groupDelimiter
hi def link groupGID            Number
hi def link groupUserListColon  groupDelimiter
hi def link groupUserList       Identifier
hi def link groupUserListSep    groupDelimiter

let b:current_syntax = "group"

let &cpo = s:cpo_save
unlet s:cpo_save