Mercurial > vim

view runtime/syntax/scdoc.vim @ 33297:6340c608ca54 v9.0.1914

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 9.0.1914: Vim9: few issues when accessing object members Commit: https://github.com/vim/vim/commit/1db151436541a3e64cdd5e3d9eb3ace1ce1e1ad0 Author: Yegappan Lakshmanan <yegappan@yahoo.com> Date: Tue Sep 19 20:34:05 2023 +0200 patch 9.0.1914: Vim9: few issues when accessing object members Problem: Vim9: few issues when accessing object members Solution: When calling an object method, check for null object. Accessing a Dict object member doesn't work. closes: #13119 closes: #13123 closes: #13124 Signed-off-by: Christian Brabandt <cb@256bit.org> Co-authored-by: Yegappan Lakshmanan <yegappan@yahoo.com>
author Christian Brabandt <cb@256bit.org>
date Tue, 19 Sep 2023 20:45:06 +0200
parents cd68a630f0d0
children
line wrap: on
line source

" Syntax file for scdoc files
" Maintainer: Gregory Anders <contact@gpanders.com>
" Last Updated: 2022-05-09
" Upstream: https://github.com/gpanders/vim-scdoc

if exists('b:current_syntax')
    finish
endif
let b:current_syntax = 'scdoc'

syntax match scdocFirstLineError "\%^.*$"
syntax match scdocFirstLineValid "\%^\S\+(\d[0-9A-Za-z]*)\%(\s\+\"[^"]*\"\%(\s\+\"[^"]*\"\)\=\)\=$"

syntax region scdocCommentError start="^;\S" end="$" keepend
syntax region scdocComment start="^; " end="$" keepend

syntax region scdocHeaderError start="^#\{3,}" end="$" keepend
syntax region scdocHeader start="^#\{1,2}" end="$" keepend

syntax match scdocIndentError "^[ ]\+"

syntax match scdocLineBreak "++$"

syntax region scdocOrderedListItem matchgroup=scdocOrderedListMarker start="^\z(\s*\)\." skip="^\z1  .*$" end="^" contains=scdocBold,scdocUnderline
syntax region scdocListItem matchgroup=scdocListMarker start="^\z(\s*\)-" skip="^\z1  .*$" end="^" contains=scdocBold,scdocUnderline

" Tables cannot start with a column
syntax match scdocTableError "^:"

syntax region scdocTable matchgroup=scdocTableEntry start="^[\[|\]][\[\-\]<=>]" end="^$" contains=scdocTableEntry,scdocTableError,scdocTableContinuation,scdocBold,scdocUnderline,scdocPre
syntax match scdocTableError "^.*$" contained
syntax match scdocTableContinuation "^   \+\S\+" contained
syntax match scdocTableEntry "^[|:][\[\-\]<=> ]" contained
syntax match scdocTableError "^[|:][\[\-\]<=> ]\S.*$" contained

syntax region scdocBold concealends matchgroup=scdocBoldDelimiter start="\\\@<!\*" end="\\\@<!\*"
syntax region scdocUnderline concealends matchgroup=scdocUnderlineDelimiter start="\<\\\@<!_" end="\\\@<!_\>"
syntax region scdocPre matchgroup=scdocPreDelimiter start="^\t*```" end="^\t*```"

syntax sync minlines=50

hi default link scdocFirstLineValid     Comment
hi default link scdocComment            Comment
hi default link scdocHeader             Title
hi default link scdocOrderedListMarker  Statement
hi default link scdocListMarker         scdocOrderedListMarker
hi default link scdocLineBreak          Special
hi default link scdocTableSpecifier     Statement
hi default link scdocTableEntry         Statement

hi default link scdocFirstLineError        Error
hi default link scdocCommentError          Error
hi default link scdocHeaderError           Error
hi default link scdocIndentError           Error
hi default link scdocTableError            Error
hi default link scdocTableError Error

hi default link scdocPreDelimiter       Delimiter

hi default scdocBold term=bold cterm=bold gui=bold
hi default scdocUnderline term=underline cterm=underline gui=underline
hi default link scdocBoldDelimiter scdocBold
hi default link scdocUnderlineDelimiter scdocUnderline