Mercurial > vim

view src/testdir/test_expand_dllpath.vim @ 25153:610e15e8778d v8.2.3113

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.3113: no error when for loop variable shadows script variable Commit: https://github.com/vim/vim/commit/442b29c968eff1c8fec1a96418aa47be9cba62ea Author: Bram Moolenaar <Bram@vim.org> Date: Mon Jul 5 22:23:00 2021 +0200 patch 8.2.3113: no error when for loop variable shadows script variable Problem: No error when for loop variable shadows script variable. Solution: Check for the error. (closes https://github.com/vim/vim/issues/8512)
author Bram Moolenaar <Bram@vim.org>
date Mon, 05 Jul 2021 22:30:03 +0200
parents 08940efa6b4e
children dbec60b8c253
line wrap: on
line source

" Test for expanding dllpath options

func s:test_expand_dllpath(optname)
  let $TEST_EXPAND_DLLPATH = '/dllpath/lib' . substitute(a:optname, '\zedll$', '.', '')
  execute 'let dllpath_save = &' . a:optname
  try
    execute 'set ' . a:optname . '=$TEST_EXPAND_DLLPATH' 
    execute 'call assert_equal("' . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 

    execute 'set ' . a:optname . '=~' . $TEST_EXPAND_DLLPATH
    let home = substitute($HOME, '\\', '/', 'g')
    execute 'call assert_equal("' . home . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 
  finally
    execute 'let &' . a:optname . ' = dllpath_save'
    let $TEST_EXPAND_DLLPATH = ''
  endtry
endfunc

func s:generate_test_if_exists(optname)
  if exists('+' . a:optname)
    execute join([
          \ 'func Test_expand_' . a:optname . '()',
          \ '  call s:test_expand_dllpath("' . a:optname . '")',
          \ 'endfunc'
          \ ], "\n")
  endif
endfunc

call s:generate_test_if_exists('luadll')
call s:generate_test_if_exists('perldll')
call s:generate_test_if_exists('pythondll')
call s:generate_test_if_exists('pythonthreedll')
call s:generate_test_if_exists('rubydll')
call s:generate_test_if_exists('tcldll')

" vim: shiftwidth=2 sts=2 expandtab