view runtime/indent.vim @ 9830:6049c1f01391 v7.4.2190

commit https://github.com/vim/vim/commit/50fa8dd00c241fa0786fe92ecc02fee4e5d28e06 Author: Bram Moolenaar <Bram@vim.org> Date: Tue Aug 9 22:58:21 2016 +0200 patch 7.4.2190 Problem: When startup test fails it's not easy to find out why. GUI test fails with Gnome. Solution: Add the help entry matches to a list an assert that. Set $HOME for Gnome to create .gnome2 directory.
author Christian Brabandt <cb@256bit.org>
date Tue, 09 Aug 2016 23:00:08 +0200
parents 19ef2bbf569c
children f37561549ec2
line wrap: on
line source

" Vim support file to switch on loading indent files for file types
"
" Maintainer:	Bram Moolenaar <Bram@vim.org>
" Last Change:	2008 Feb 22

if exists("did_indent_on")
  finish
endif
let did_indent_on = 1

augroup filetypeindent
  au FileType * call s:LoadIndent()
  func! s:LoadIndent()
    if exists("b:undo_indent")
      exe b:undo_indent
      unlet! b:undo_indent b:did_indent
    endif
    let s = expand("<amatch>")
    if s != ""
      if exists("b:did_indent")
	unlet b:did_indent
      endif

      " When there is a dot it is used to separate filetype names.  Thus for
      " "aaa.bbb" load "indent/aaa.vim" and then "indent/bbb.vim".
      for name in split(s, '\.')
	exe 'runtime! indent/' . name . '.vim'
      endfor
    endif
  endfunc
augroup END