Mercurial > vim

view runtime/syntax/services.vim @ 27455:6045bf58926d v8.2.4256

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.4256: MS-Windows: compiler warnings when compiled with /W4 Commit: https://github.com/vim/vim/commit/135e15251efd96c960e51e8ab31333c2d6887983 Author: K.Takata <kentkt@csc.jp> Date: Sat Jan 29 15:27:58 2022 +0000 patch 8.2.4256: MS-Windows: compiler warnings when compiled with /W4 Problem: MS-Windows: compiler warnings when compiled with /W4. Solution: Small adjustments to the code. (Ken Takata, closes https://github.com/vim/vim/issues/9659)
author Bram Moolenaar <Bram@vim.org>
date Sat, 29 Jan 2022 16:30:04 +0100
parents 1218c5353e2b
children
line wrap: on
line source

" Vim syntax file
" Language:             services(5) - Internet network services list
" Previous Maintainer:  Nikolai Weibull <now@bitwi.se>
" Latest Revision:      2006-04-19

if exists("b:current_syntax")
  finish
endif

let s:cpo_save = &cpo
set cpo&vim

syn match   servicesBegin     display '^'
                              \ nextgroup=servicesName,servicesComment

syn match   servicesName      contained display '[[:graph:]]\+'
                              \ nextgroup=servicesPort skipwhite

syn match   servicesPort      contained display '\d\+'
                              \ nextgroup=servicesPPDiv,servicesPPDivDepr
                              \ skipwhite

syn match   servicesPPDiv     contained display '/'
                              \ nextgroup=servicesProtocol skipwhite

syn match   servicesPPDivDepr contained display ','
                              \ nextgroup=servicesProtocol skipwhite

syn match   servicesProtocol  contained display '\S\+'
                              \ nextgroup=servicesAliases,servicesComment
                              \ skipwhite

syn match   servicesAliases   contained display '\S\+'
                              \ nextgroup=servicesAliases,servicesComment
                              \ skipwhite

syn keyword servicesTodo      contained TODO FIXME XXX NOTE

syn region  servicesComment   display oneline start='#' end='$'
                              \ contains=servicesTodo,@Spell

hi def link servicesTodo      Todo
hi def link servicesComment   Comment
hi def link servicesName      Identifier
hi def link servicesPort      Number
hi def link servicesPPDiv     Delimiter
hi def link servicesPPDivDepr Error
hi def link servicesProtocol  Type
hi def link servicesAliases   Macro

let b:current_syntax = "services"

let &cpo = s:cpo_save
unlet s:cpo_save