Mercurial > vim

view runtime/syntax/debsources.vim @ 11054:576238eda5a4 v8.0.0416

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.0416: setting v:progpath is not quite right commit https://github.com/vim/vim/commit/436631969716e056feca47480976100b70283370 Author: Bram Moolenaar <Bram@vim.org> Date: Sun Mar 5 14:29:12 2017 +0100 patch 8.0.0416: setting v:progpath is not quite right Problem: Setting v:progpath is not quite right. Solution: On MS-Windows add the extension. On Unix use the full path for a relative directory. (partly by James McCoy, closes #1531)
author Christian Brabandt <cb@256bit.org>
date Sun, 05 Mar 2017 14:30:04 +0100
parents 9a75c8a1b8b1
children 63b0b7b79b25
line wrap: on
line source

" Vim syntax file
" Language:     Debian sources.list
" Maintainer:   Debian Vim Maintainers <pkg-vim-maintainers@lists.alioth.debian.org>
" Former Maintainer: Matthijs Mohlmann <matthijs@cacholong.nl>
" Last Change: 2016 Nov 12
" URL: https://anonscm.debian.org/cgit/pkg-vim/vim.git/plain/runtime/syntax/debsources.vim

" Standard syntax initialization
if exists("b:current_syntax")
  finish
endif

" case sensitive
syn case match

" A bunch of useful keywords
syn match debsourcesKeyword        /\(deb-src\|deb\|main\|contrib\|non-free\|restricted\|universe\|multiverse\)/

" Match comments
syn match debsourcesComment        /#.*/  contains=@Spell

let s:cpo = &cpo
set cpo-=C
let s:supported = [
      \ 'oldstable', 'stable', 'testing', 'unstable', 'experimental',
      \ 'squeeze', 'wheezy', 'jessie', 'stretch', 'sid', 'rc-buggy',
      \
      \ 'precise', 'trusty', 'xenial', 'yakkety', 'zesty', 'devel'
      \ ]
let s:unsupported = [
      \ 'buzz', 'rex', 'bo', 'hamm', 'slink', 'potato',
      \ 'woody', 'sarge', 'etch', 'lenny',
      \
      \ 'warty', 'hoary', 'breezy', 'dapper', 'edgy', 'feisty',
      \ 'gutsy', 'hardy', 'intrepid', 'jaunty', 'karmic', 'lucid',
      \ 'maverick', 'natty', 'oneiric', 'quantal', 'raring', 'saucy',
      \ 'utopic', 'vivid', 'wily'
      \ ]
let &cpo=s:cpo

" Match uri's
syn match debsourcesUri            +\(https\?://\|ftp://\|[rs]sh://\|debtorrent://\|\(cdrom\|copy\|file\):\)[^' 	<>"]\++
exe 'syn match debsourcesDistrKeyword   +\([[:alnum:]_./]*\)\('. join(s:supported, '\|'). '\)\([-[:alnum:]_./]*\)+'
exe 'syn match debsourcesUnsupportedDistrKeyword +\([[:alnum:]_./]*\)\('. join(s:unsupported, '\|') .'\)\([-[:alnum:]_./]*\)+'

" Associate our matches and regions with pretty colours
hi def link debsourcesLine                    Error
hi def link debsourcesKeyword                 Statement
hi def link debsourcesDistrKeyword            Type
hi def link debsourcesUnsupportedDistrKeyword WarningMsg
hi def link debsourcesComment                 Comment
hi def link debsourcesUri                     Constant

let b:current_syntax = "debsources"