Mercurial > vim

view src/testdir/test_help.vim @ 16021:5417a7f802ff v8.1.1016

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.1.1016: MS-Windows: No color in shell when using "!" in 'guioptions commit https://github.com/vim/vim/commit/049ca59236d5a981f23cf5dfe40f54536fe7cad2 Author: Bram Moolenaar <Bram@vim.org> Date: Sun Mar 17 16:59:44 2019 +0100 patch 8.1.1016: MS-Windows: No color in shell when using "!" in 'guioptions Problem: MS-Windows: No color in shell when using "!" in 'guioptions. Solution: Don't stop termcap when using a terminal window for the shell. (vim-jp, closes #4117)
author Bram Moolenaar <Bram@vim.org>
date Sun, 17 Mar 2019 17:00:13 +0100
parents e1deb00ffc27
children d0dfb3b0fe31
line wrap: on
line source

" Tests for :help

func Test_help_restore_snapshot()
  help
  set buftype=
  help
  edit x
  help
  helpclose
endfunc

func Test_help_errors()
  call assert_fails('help doesnotexist', 'E149:')
  call assert_fails('help!', 'E478:')

  new
  set keywordprg=:help
  call setline(1, "   ")
  call assert_fails('normal VK', 'E349:')
  bwipe!
endfunc

func Test_help_keyword()
  new
  set keywordprg=:help
  call setline(1, "  Visual ")
  normal VK
  call assert_match('^Visual mode', getline('.'))
  call assert_equal('help', &ft)
  close
  bwipe!
endfunc

func Test_help_local_additions()
  call mkdir('Xruntime/doc', 'p')
  call writefile(['*mydoc.txt* my awesome doc'], 'Xruntime/doc/mydoc.txt')
  call writefile(['*mydoc-ext.txt* my extended awesome doc'], 'Xruntime/doc/mydoc-ext.txt')
  let rtp_save = &rtp
  set rtp+=./Xruntime
  help
  1
  call search('mydoc.txt')
  call assert_equal('|mydoc.txt| my awesome doc', getline('.'))
  1
  call search('mydoc-ext.txt')
  call assert_equal('|mydoc-ext.txt| my extended awesome doc', getline('.'))
  close

  call delete('Xruntime', 'rf')
  let &rtp = rtp_save
endfunc