Mercurial > vim

view src/testdir/test_tabline.vim @ 8872:4d4de770f970 v7.4.1723

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
commit https://github.com/vim/vim/commit/f73d3bc253fa79ad220f52f04b93e782e95a9d43 Author: Bram Moolenaar <Bram@vim.org> Date: Mon Apr 11 21:55:15 2016 +0200 patch 7.4.1723 Problem: When using try/catch in 'tabline' it is still considered an error and the tabline will be disabled. Solution: Check did_emsg instead of called_emsg. (haya14busa, closes https://github.com/vim/vim/issues/746)
author Christian Brabandt <cb@256bit.org>
date Mon, 11 Apr 2016 22:00:05 +0200
parents
children ccab37bb9ac9
line wrap: on
line source

function! TablineWithCaughtError()
  let s:func_in_tabline_called = 1
  try
    call eval('unknown expression')
  catch
  endtry
  return ''
endfunction

function! TablineWithError()
  let s:func_in_tabline_called = 1
  call eval('unknown expression')
  return ''
endfunction

function! Test_caught_error_in_tabline()
  let showtabline_save = &showtabline
  set showtabline=2
  let s:func_in_tabline_called = 0
  let tabline = '%{TablineWithCaughtError()}'
  let &tabline = tabline
  redraw!
  call assert_true(s:func_in_tabline_called)
  call assert_equal(tabline, &tabline)
  set tabline=
  let &showtabline = showtabline_save
endfunction

function! Test_tabline_will_be_disabled_with_error()
  let showtabline_save = &showtabline
  set showtabline=2
  let s:func_in_tabline_called = 0
  let tabline = '%{TablineWithError()}'
  try
    let &tabline = tabline
    redraw!
  catch
  endtry
  call assert_true(s:func_in_tabline_called)
  call assert_equal('', &tabline)
  set tabline=
  let &showtabline = showtabline_save
endfunction