Mercurial > vim

view src/testdir/test_expand_dllpath.vim @ 21783:483dc3fd596c v8.2.1441

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.1441: running tests in tiny version gives error for summarize.vim Commit: https://github.com/vim/vim/commit/c771908681bc9ee7689d83e09104cf4c6f984326 Author: Bram Moolenaar <Bram@vim.org> Date: Thu Aug 13 19:42:39 2020 +0200 patch 8.2.1441: running tests in tiny version gives error for summarize.vim Problem: Running tests in tiny version gives error for summarize.vim. Solution: Set 'cpoptions' to allow for line continuation. Restore redirecting test output to /dev/null.
author Bram Moolenaar <Bram@vim.org>
date Thu, 13 Aug 2020 19:45:04 +0200
parents 08940efa6b4e
children dbec60b8c253
line wrap: on
line source

" Test for expanding dllpath options

func s:test_expand_dllpath(optname)
  let $TEST_EXPAND_DLLPATH = '/dllpath/lib' . substitute(a:optname, '\zedll$', '.', '')
  execute 'let dllpath_save = &' . a:optname
  try
    execute 'set ' . a:optname . '=$TEST_EXPAND_DLLPATH' 
    execute 'call assert_equal("' . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 

    execute 'set ' . a:optname . '=~' . $TEST_EXPAND_DLLPATH
    let home = substitute($HOME, '\\', '/', 'g')
    execute 'call assert_equal("' . home . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 
  finally
    execute 'let &' . a:optname . ' = dllpath_save'
    let $TEST_EXPAND_DLLPATH = ''
  endtry
endfunc

func s:generate_test_if_exists(optname)
  if exists('+' . a:optname)
    execute join([
          \ 'func Test_expand_' . a:optname . '()',
          \ '  call s:test_expand_dllpath("' . a:optname . '")',
          \ 'endfunc'
          \ ], "\n")
  endif
endfunc

call s:generate_test_if_exists('luadll')
call s:generate_test_if_exists('perldll')
call s:generate_test_if_exists('pythondll')
call s:generate_test_if_exists('pythonthreedll')
call s:generate_test_if_exists('rubydll')
call s:generate_test_if_exists('tcldll')

" vim: shiftwidth=2 sts=2 expandtab