Mercurial > vim

view runtime/plugin/manpager.vim @ 26739:47ad45fb433a v8.2.3898

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.3898: Vim9: not sufficient testing for variable initialization Commit: https://github.com/vim/vim/commit/fb9dcb080b5143d3021a8c1d6deaf143f2ca3a48 Author: Bram Moolenaar <Bram@vim.org> Date: Sat Dec 25 22:00:49 2021 +0000 patch 8.2.3898: Vim9: not sufficient testing for variable initialization Problem: Vim9: not sufficient testing for variable initialization. Solution: Add another test case.
author Bram Moolenaar <Bram@vim.org>
date Sat, 25 Dec 2021 23:15:03 +0100
parents 29ec2c198c8d
children f3ec3c57e070
line wrap: on
line source

" Vim plugin for using Vim as manpager.
" Maintainer: Enno Nagel <ennonagel+vim@gmail.com>
" Last Change: 2020 Aug 05

command! -nargs=0 MANPAGER call s:ManPager() | delcommand MANPAGER

function! s:ManPager()
  set nocompatible
  if exists('+viminfofile')
    set viminfofile=NONE
  endif
  set noswapfile 

  setlocal ft=man
  runtime ftplugin/man.vim
  setlocal buftype=nofile bufhidden=hide iskeyword+=: modifiable

  " Emulate 'col -b'
  silent! keepj keepp %s/\v(.)\b\ze\1?//ge

  " Remove ansi sequences
  silent! keepj keepp %s/\v\e\[%(%(\d;)?\d{1,2})?[mK]//ge

  " Remove empty lines above the header
  call cursor(1, 1)
  let n = search(".*(.*)", "c")
  if n > 1
    exe "1," . n-1 . "d"
  endif
  setlocal nomodified readonly

  syntax on
endfunction