Mercurial > vim

view src/testdir/test_messages.vim @ 13537:3fa880445c99 v8.0.1642

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.1642: running Vim in terminal fails with two windows commit https://github.com/vim/vim/commit/15a1c3fdc19499c267e4dc664aa0de9d65a08cad Author: Bram Moolenaar <Bram@vim.org> Date: Sun Mar 25 18:56:25 2018 +0200 patch 8.0.1642: running Vim in terminal fails with two windows Problem: Running Vim in terminal fails with two windows. Solution: Pass the number of rows to RunVimInTerminal().
author Christian Brabandt <cb@256bit.org>
date Sun, 25 Mar 2018 19:00:07 +0200
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction