Mercurial > vim

view src/testdir/test_messages.vim @ 12855:3c09e451af3a v8.0.1304

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.1304: CTRL-G/CTRL-T don't work with incsearch and empty pattern commit https://github.com/vim/vim/commit/d0480097177369a6ed91d47aba189ae647afcd68 Author: Bram Moolenaar <Bram@vim.org> Date: Thu Nov 16 22:20:39 2017 +0100 patch 8.0.1304: CTRL-G/CTRL-T don't work with incsearch and empty pattern Problem: CTRL-G/CTRL-T don't work with incsearch and empty pattern. Solution: Use the last search pattern. (Christian Brabandt, closes https://github.com/vim/vim/issues/2292)
author Christian Brabandt <cb@256bit.org>
date Thu, 16 Nov 2017 22:30:06 +0100
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction