Mercurial > vim

view src/testdir/test_messages.vim @ 13678:39fcaaa973db v8.0.1711

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.1711: term_setsize() is not implemented yet commit https://github.com/vim/vim/commit/a42d363bac8a581afe769c370db70cf833767c41 Author: Bram Moolenaar <Bram@vim.org> Date: Sat Apr 14 17:05:38 2018 +0200 patch 8.0.1711: term_setsize() is not implemented yet Problem: Term_setsize() is not implemented yet. Solution: Implement it.
author Christian Brabandt <cb@256bit.org>
date Sat, 14 Apr 2018 17:15:05 +0200
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction