patch 9.1.0116: win_split_ins may not check available room Commit: https://github.com/vim/vim/commit/0fd44a5ad81ade342cb54d8984965bdedd2272c8 Author: Sean Dewar <6256228+seandewar@users.noreply.github.com> Date: Tue Feb 20 20:28:15 2024 +0100 patch 9.1.0116: win_split_ins may not check available room Problem: win_split_ins has no check for E36 when moving an existing window Solution: check for room and fix the issues in f_win_splitmove() (Sean Dewar) win_split_ins has no check for E36 when moving an existing window, allowing for layouts with many overlapping zero-sized windows to be created (which may also cause drawing issues with tablines and such). f_win_splitmove also has some bugs. So check for room and fix the issues in f_win_splitmove. Handle failure in the two relevant win_split_ins callers by restoring the original layout, and factor the common logic into win_splitmove. Don't check for room when opening an autocommand window, as it's a temporary window that's rarely interacted with or drawn anyhow, and is rather important for some autocommands. Issues fixed in f_win_splitmove: - Error if splitting is disallowed. - Fix heap-use-after-frees if autocommands fired from switching to "targetwin" close "wp" or "oldwin". - Fix splitting the wrong window if autocommands fired from switching to "targetwin" switch to a different window. - Ensure -1 is returned for all errors. Also handle allocation failure a bit earlier in make_snapshot (callers, except win_splitmove, don't really care if a snapshot can't be made, so just ignore the return value). Note: Test_smoothscroll_in_zero_width_window failed after these changes with E36, as it was using the previous behaviour to create a zero-width window. I've fixed the test such that it fails with UBSAN as expected when v9.0.1367 is reverted (and simplified it too). related: #14042 Signed-off-by: Sean Dewar <6256228+seandewar@users.noreply.github.com> Signed-off-by: Christian Brabandt <cb@256bit.org>

" Test the ":move" command.

source check.vim
source screendump.vim

func Test_move()
  enew!
  call append(0, ['line 1', 'line 2', 'line 3'])
  g /^$/ delete _
  set nomodified

  move .
  call assert_equal(['line 1', 'line 2', 'line 3'], getline(1, 3))
  call assert_false(&modified)

  1,2move 0
  call assert_equal(['line 1', 'line 2', 'line 3'], getline(1, 3))
  call assert_false(&modified)

  1,3move 3
  call assert_equal(['line 1', 'line 2', 'line 3'], getline(1, 3))
  call assert_false(&modified)

  1move 2
  call assert_equal(['line 2', 'line 1', 'line 3'], getline(1, 3))
  call assert_true(&modified)
  set nomodified

  3move 0
  call assert_equal(['line 3', 'line 2', 'line 1'], getline(1, 3))
  call assert_true(&modified)
  set nomodified

  2,3move 0
  call assert_equal(['line 2', 'line 1', 'line 3'], getline(1, 3))
  call assert_true(&modified)
  set nomodified

  call assert_fails('1,2move 1', 'E134:')
  call assert_fails('2,3move 2', 'E134:')
  call assert_fails("move -100", 'E16:')
  call assert_fails("move +100", 'E16:')
  call assert_fails('move', 'E16:')
  call assert_fails("move 'r", 'E20:')

  %bwipeout!
endfunc

func Test_move_undo()
  CheckRunVimInTerminal

  let lines =<< trim END
      call setline(1, ['First', 'Second', 'Third', 'Fourth'])
  END
  call writefile(lines, 'Xtest_move_undo.vim', 'D')
  let buf = RunVimInTerminal('-S Xtest_move_undo.vim', #{rows: 10, cols: 60, statusoff: 2})

  call term_sendkeys(buf, "gg:move +1\<CR>")
  call VerifyScreenDump(buf, 'Test_move_undo_1', {})

  " here the display would show the last few lines scrolled down
  call term_sendkeys(buf, "u")
  call term_sendkeys(buf, ":\<Esc>")
  call VerifyScreenDump(buf, 'Test_move_undo_2', {})

  call StopVimInTerminal(buf)
endfunc


" vim: shiftwidth=2 sts=2 expandtab