Mercurial > vim

view src/testdir/test_messages.vim @ 11345:329653a02657 v8.0.0558

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.0558: :ownsyntax is not tested commit https://github.com/vim/vim/commit/f8ec998613d8037e345f4e7e08460dfc15c528a9 Author: Bram Moolenaar <Bram@vim.org> Date: Sun Apr 9 15:41:31 2017 +0200 patch 8.0.0558: :ownsyntax is not tested Problem: The :ownsyntax command is not tested. Solution: Add a test. (Dominique Pelle, closes https://github.com/vim/vim/issues/1622)
author Christian Brabandt <cb@256bit.org>
date Sun, 09 Apr 2017 15:45:03 +0200
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction