Mercurial > vim

view src/testdir/test_messages.vim @ 12905:30b0d784c870 v8.0.1329

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.1329: when a flaky test fails it also often fails the second time commit https://github.com/vim/vim/commit/550586015232ecc4f68b3479fa8ba2cf81c76e7b Author: Bram Moolenaar <Bram@vim.org> Date: Tue Nov 21 15:14:51 2017 +0100 patch 8.0.1329: when a flaky test fails it also often fails the second time Problem: When a flaky test fails it also often fails the second time. Solution: Sleep a couple of seconds before the second try.
author Christian Brabandt <cb@256bit.org>
date Tue, 21 Nov 2017 15:15:05 +0100
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction