Mercurial > vim

view src/testdir/test_source_utf8.vim @ 10609:302aedeed8c9 v8.0.0194

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.0194: profile tests fails if total and self time are equal commit https://github.com/vim/vim/commit/e32bbded641a5da0263ecf82f9ccc95a8e0a089e Author: Bram Moolenaar <Bram@vim.org> Date: Sun Jan 15 21:12:48 2017 +0100 patch 8.0.0194: profile tests fails if total and self time are equal Problem: Profile tests fails if total and self time are equal. Solution: Make one time optional.
author Christian Brabandt <cb@256bit.org>
date Sun, 15 Jan 2017 21:15:04 +0100
parents bff8a09016a5
children aa658b33f25a
line wrap: on
line source

" Test the :source! command
if !has('multi_byte')
  finish
endif

func Test_source_utf8()
  " check that sourcing a script with 0x80 as second byte works
  new
  call setline(1, [':%s/àx/--à1234--/g', ':%s/Àx/--À1234--/g'])
  write! Xscript
  bwipe!
  new
  call setline(1, [' àx ', ' Àx '])
  source! Xscript | echo
  call assert_equal(' --à1234-- ', getline(1))
  call assert_equal(' --À1234-- ', getline(2))
  bwipe!
  call delete('Xscript')
endfunc

func Test_source_latin()
  " check that sourcing a latin1 script with a 0xc0 byte works
  new
  call setline(1, ["call feedkeys('r')", "call feedkeys('\xc0', 'xt')"])
  write! Xscript
  bwipe!
  new
  call setline(1, ['xxx'])
  source Xscript
  call assert_equal("\u00c0xx", getline(1))
  bwipe!
  call delete('Xscript')
endfunc