Mercurial > vim

view src/testdir/test_expand_dllpath.vim @ 28929:2ac9beab876c v8.2.4987

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.4987: after deletion a small fold may be closable Commit: https://github.com/vim/vim/commit/3fcccf94e8bc142d2c79c3b62087145896df6b36 Author: Brandon Simmons <simmsbra@gmail.com> Date: Fri May 20 18:25:21 2022 +0100 patch 8.2.4987: after deletion a small fold may be closable Problem: After deletion a small fold may be closable. Solution: Check for a reverse range. (Brandon Simmons, closes https://github.com/vim/vim/issues/10457)
author Bram Moolenaar <Bram@vim.org>
date Fri, 20 May 2022 19:30:06 +0200
parents 08940efa6b4e
children dbec60b8c253
line wrap: on
line source

" Test for expanding dllpath options

func s:test_expand_dllpath(optname)
  let $TEST_EXPAND_DLLPATH = '/dllpath/lib' . substitute(a:optname, '\zedll$', '.', '')
  execute 'let dllpath_save = &' . a:optname
  try
    execute 'set ' . a:optname . '=$TEST_EXPAND_DLLPATH' 
    execute 'call assert_equal("' . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 

    execute 'set ' . a:optname . '=~' . $TEST_EXPAND_DLLPATH
    let home = substitute($HOME, '\\', '/', 'g')
    execute 'call assert_equal("' . home . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')' 
  finally
    execute 'let &' . a:optname . ' = dllpath_save'
    let $TEST_EXPAND_DLLPATH = ''
  endtry
endfunc

func s:generate_test_if_exists(optname)
  if exists('+' . a:optname)
    execute join([
          \ 'func Test_expand_' . a:optname . '()',
          \ '  call s:test_expand_dllpath("' . a:optname . '")',
          \ 'endfunc'
          \ ], "\n")
  endif
endfunc

call s:generate_test_if_exists('luadll')
call s:generate_test_if_exists('perldll')
call s:generate_test_if_exists('pythondll')
call s:generate_test_if_exists('pythonthreedll')
call s:generate_test_if_exists('rubydll')
call s:generate_test_if_exists('tcldll')

" vim: shiftwidth=2 sts=2 expandtab