Mercurial > vim

view src/testdir/test_mksession_utf8.vim @ 32732:257ab4ee8e4a v9.0.1686

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 9.0.1686: undotree() only works for the current buffer Commit: https://github.com/vim/vim/commit/5fee11114975b7405b7ccd3ee8758e54bf559760 Author: Devin J. Pohly <djpohly@gmail.com> Date: Sun Apr 23 20:26:59 2023 -0500 patch 9.0.1686: undotree() only works for the current buffer Problem: undotree() only works for the current buffer Solution: Add an optional "buffer number" parameter to undotree(). If omitted, use the current buffer for backwards compatibility. closes: #4001 closes: #12292 Signed-off-by: Christian Brabandt <cb@256bit.org> Co-authored-by: zeertzjq <zeertzjq@outlook.com> Co-authored-by: Devin J. Pohly <djpohly@gmail.com>
author Christian Brabandt <cb@256bit.org>
date Fri, 11 Aug 2023 23:00:05 +0200
parents 6990c1160ea5
children
line wrap: on
line source

" Test for :mksession, :mkview and :loadview in utf-8 encoding

set encoding=utf-8
scriptencoding utf-8

source check.vim
CheckFeature mksession

func Test_mksession_utf8()
  tabnew
  let wrap_save = &wrap
  set sessionoptions=buffers splitbelow fileencoding=utf-8
  call setline(1, [
    \   'start:',
    \   'no multibyte chAracter',
    \   '	one leaDing tab',
    \   '    four leadinG spaces',
    \   'two		consecutive tabs',
    \   'two	tabs	in one line',
    \   'one … multibyteCharacter',
    \   'a “b” two multiByte characters',
    \   '“c”1€ three mulTibyte characters'
    \ ])
  let tmpfile = tempname()
  exec 'w! ' . tmpfile
  /^start:
  set wrap
  vsplit
  norm! j16|
  split
  norm! j16|
  split
  norm! j16|
  split
  norm! j8|
  split
  norm! j8|
  split
  norm! j16|
  split
  norm! j16|
  split
  norm! j16|
  wincmd l

  set nowrap
  /^start:
  norm! j16|3zl
  split
  norm! j016|3zl
  split
  norm! j016|3zl
  split
  norm! j08|3zl
  split
  norm! j08|3zl
  split
  norm! j016|3zl
  split
  norm! j016|3zl
  split
  norm! j016|3zl
  split
  call wincol()
  mksession! test_mks.out
  let li = filter(readfile('test_mks.out'), 'v:val =~# "\\(^ *normal! 0\\|^ *exe ''normal!\\)"')
  let expected =<< trim [DATA]
    normal! 016|
    normal! 016|
    normal! 016|
    normal! 08|
    normal! 08|
    normal! 016|
    normal! 016|
    normal! 016|
      exe 'normal! ' . s:c . '|zs' . 16 . '|'
      normal! 016|
      exe 'normal! ' . s:c . '|zs' . 16 . '|'
      normal! 016|
      exe 'normal! ' . s:c . '|zs' . 16 . '|'
      normal! 016|
      exe 'normal! ' . s:c . '|zs' . 8 . '|'
      normal! 08|
      exe 'normal! ' . s:c . '|zs' . 8 . '|'
      normal! 08|
      exe 'normal! ' . s:c . '|zs' . 16 . '|'
      normal! 016|
      exe 'normal! ' . s:c . '|zs' . 16 . '|'
      normal! 016|
      exe 'normal! ' . s:c . '|zs' . 16 . '|'
      normal! 016|
      exe 'normal! ' . s:c . '|zs' . 16 . '|'
      normal! 016|
  [DATA]

  call assert_equal(expected, li)
  tabclose!

  call delete('test_mks.out')
  call delete(tmpfile)
  let &wrap = wrap_save
  set sessionoptions& splitbelow& fileencoding&
endfunc

" vim: shiftwidth=2 sts=2 expandtab