Mercurial > vim

view src/testdir/test_messages.vim @ 11912:22658e33203f v8.0.0836

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.0.0836: can abandon a terminal buffer after making a change commit https://github.com/vim/vim/commit/20e6cd07baed8992e7a509ccef7f111ffcded44d Author: Bram Moolenaar <Bram@vim.org> Date: Tue Aug 1 20:25:22 2017 +0200 patch 8.0.0836: can abandon a terminal buffer after making a change Problem: When a terminal buffer is changed it can still be accidentally abandoned. Solution: When making a change reset the 'buftype' option.
author Christian Brabandt <cb@256bit.org>
date Tue, 01 Aug 2017 20:30:04 +0200
parents 9200836eee15
children d111462e0173
line wrap: on
line source

" Tests for :messages

function Test_messages()
  let oldmore = &more
  try
    set nomore
    " Avoid the "message maintainer" line.
    let $LANG = ''

    let arr = map(range(10), '"hello" . v:val')
    for s in arr
      echomsg s | redraw
    endfor
    let result = ''

    " get last two messages
    redir => result
    2messages | redraw
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(["hello8", "hello9"], msg_list)

    " clear messages without last one
    1messages clear
    redir => result
    redraw | messages
    redir END
    let msg_list = split(result, "\n")
    call assert_equal(['hello9'], msg_list)

    " clear all messages
    messages clear
    redir => result
    redraw | messages
    redir END
    call assert_equal('', result)
  finally
    let &more = oldmore
  endtry
endfunction