Mercurial > vim

view src/testdir/test_shift.vim @ 19922:1f42c49c3d29 v8.2.0517

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
patch 8.2.0517: Vim9: cannot separate "func" and "func(): void" Commit: https://github.com/vim/vim/commit/4c68375057c25e99656bc996d3fa5c6b0b6a7e6a Author: Bram Moolenaar <Bram@vim.org> Date: Sun Apr 5 21:38:23 2020 +0200 patch 8.2.0517: Vim9: cannot separate "func" and "func(): void" Problem: Vim9: cannot separate "func" and "func(): void". Solution: Use VAR_ANY for "any" and VAR_UNKNOWN for "no type".
author Bram Moolenaar <Bram@vim.org>
date Sun, 05 Apr 2020 21:45:25 +0200
parents c945f1d03b1c
children 08940efa6b4e
line wrap: on
line source

" Test shifting lines with :> and :<

source check.vim

func Test_ex_shift_right()
  set shiftwidth=2

  " shift right current line.
  call setline(1, range(1, 5))
  2
  >
  3
  >>
  call assert_equal(['1',
        \            '  2',
        \            '    3',
        \            '4',
        \            '5'], getline(1, '$'))

  " shift right with range.
  call setline(1, range(1, 4))
  2,3>>
  call assert_equal(['1',
        \            '    2',
        \            '    3',
        \            '4',
        \            '5'], getline(1, '$'))

  " shift right with range and count.
  call setline(1, range(1, 4))
  2>3
  call assert_equal(['1',
        \            '  2',
        \            '  3',
        \            '  4',
        \            '5'], getline(1, '$'))

  bw!
  set shiftwidth&
endfunc

func Test_ex_shift_left()
  set shiftwidth=2

  call setline(1, range(1, 5))
  %>>>

  " left shift current line.
  2<
  3<<
  4<<<<<
  call assert_equal(['      1',
        \            '    2',
        \            '  3',
        \            '4',
        \            '      5'], getline(1, '$'))

  " shift right with range.
  call setline(1, range(1, 5))
  %>>>
  2,3<<
  call assert_equal(['      1',
        \            '  2',
        \            '  3',
        \            '      4',
        \            '      5'], getline(1, '$'))

  " shift right with range and count.
  call setline(1, range(1, 5))
  %>>>
  2<<3
  call assert_equal(['      1',
     \               '  2',
     \               '  3',
     \               '  4',
     \               '      5'], getline(1, '$'))

  bw!
  set shiftwidth&
endfunc

func Test_ex_shift_rightleft()
  CheckFeature rightleft

  set shiftwidth=2 rightleft

  call setline(1, range(1, 4))
  2,3<<
  call assert_equal(['1',
        \             '    2',
        \             '    3',
        \             '4'], getline(1, '$'))

  3,4>
  call assert_equal(['1',
        \            '    2',
        \            '  3',
        \            '4'], getline(1, '$'))

  bw!
  set rightleft& shiftwidth&
endfunc

func Test_ex_shift_errors()
  call assert_fails('><', 'E488:')
  call assert_fails('<>', 'E488:')

  call assert_fails('>!', 'E477:')
  call assert_fails('<!', 'E477:')

  call assert_fails('2,1>', 'E493:')
  call assert_fails('2,1<', 'E493:')
endfunc